''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' "check_dell_omreport.wsf"
'
' This script was initially developed by Anstat Pty Ltd for internal use,
' and has kindly been made available to the Open Source community for
' redistribution and further development under the terms of the
' GNU General Public License: http://www.gnu.org/licenses/gpl.html
' 
' This script is supplied 'as-is', in the hope that it will be useful, but
' neither Anstat Pty Ltd nor the authors make any warranties or guarantees
' as to its correct operation, including its intended function.
' 
' Or in other words:
'         Test it yourself, and make sure it works for YOU.
' 
' Author: George Hansper               e-mail:  Name.Surname@anstat.com.au
'
' --------------------------------------------------------------------------------------------
'
' This plugin will return the status of the a Dell Perc RAID Array
' This script requires the command line utility "omreport.exe"
' from the package: "Dell OpenManage Server Administrator"
'
' *** Warning: this script has not been tested exhaustively - use at own risk ***
'
' This script is loosely based on an equivalent Perl script for Linux.
'

<job>
<runtime>
  <description>
Check status of Dell RAID array using Dell OpenManage Server Administrator utility "omreport"

This script requires omreport version 2.x
This is installed with Dell OpenManage Server Administrator version 4.x

Example NRPE_NT Usage:
	command[check_dell_omreport]=c:\winnt\system32\cscript.exe //NoLogo //T:10 c:\nrpe_nt\check_dell_omreport.wsf

  </description>
  </runtime>
<script language="VBScript">
Dim strMessage, strLine
Dim ndx
Const intOK = 0
Const intWarning = 1
Const intCritical = 2
Dim intExit

Set objRegexp = New RegExp
With objRegexp
.Global = False
.IgnoreCase = True
.Pattern = "."
End With

Set objShell = WScript.CreateObject("WScript.Shell")

Dim strPathToOmreport
' The strPathToOmreport variable may be used if the omreport CLI command is not on the PATH
strPathToOmreport = "C:\Program Files\Dell\SysMgt\oma\bin\"
strPathToOmreport = ""

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Get ID of each controller
Dim nCtrlrs
Dim ctrlrId(), ctrlrName(), ctrlrStatus(), ctrlrState()
Dim ctrlrBatteryId(), ctrlrBatteryStatus(), ctrlrBatteryState()
Dim strField, strValue
nCtrlrs = 0
objRegexp.Pattern = "([^:]*):(.*)"

Set objExecObject = objShell.Exec(strPathToOmreport & "omreport.exe storage controller -fmt lst")

Do Until objExecObject.StdOut.AtEndOfStream
	strLine = objExecObject.StdOut.ReadLine()
	strField = ""
	if objRegexp.Test(strLine) = True Then
		strField = objRegexp.Replace(strLine, "$1")
		strField = Trim(strField)
		strValue = objRegexp.Replace(strLine, "$2")
		strValue = Trim(strValue)
	Else
		' Wscript.Echo ":( " & strLine 
	End If
	If ( Lcase(strField) = "id" ) Then
		nCtrlrs = nCtrlrs + 1
		ReDim Preserve ctrlrId(nCtrlrs-1)
		ReDim Preserve ctrlrName(nCtrlrs-1)
		ReDim Preserve ctrlrStatus(nCtrlrs-1)
		ReDim Preserve ctrlrState(nCtrlrs-1)
		ReDim Preserve ctrlrBatteryID(nCtrlrs-1)
		ReDim Preserve ctrlrBatteryStatus(nCtrlrs-1)
		ReDim Preserve ctrlrBatteryState(nCtrlrs-1)
		ctrlrId(nCtrlrs-1) = strValue
	ElseIf ( Lcase(strField) = "name" ) Then
		ctrlrName(nCtrlrs-1) = strValue
	ElseIf ( Lcase(strField) = "status" ) Then
		ctrlrStatus(nCtrlrs-1) = strValue
	ElseIf ( Lcase(strField) = "state" ) Then
		ctrlrState(nCtrlrs-1) = strValue
	End If

	' Wscript.Echo ">> " & strField & "=" & strValue
Loop

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Loop through controllers, to get each vdisk (disk array) from each controller, and battery state

Dim nVdisks
Dim vdiskId(), vdiskStatus(), vdiskState(), vdiskCtrlrNdx(), vdiskCtrlrID(), vdiskProgress()
nVdisks = 0

ndx=0
Do Until ( ndx >= nCtrlrs )
	' Wscript.Echo ndx & ">> " & ctrlrId(ndx) & "=" & ctrlrName(ndx)
	Set objExecObject = objShell.Exec(strPathToOmreport & "omreport.exe storage vdisk controller=" & ctrlrId(ndx) & " -fmt lst")
	Do Until objExecObject.StdOut.AtEndOfStream
		strLine = objExecObject.StdOut.ReadLine()
		' Using same objRegexp.Pattern as above
		strField = ""
		if ( objRegexp.Test(strLine) = True ) Then
			strField = objRegexp.Replace(strLine, "$1")
			strField = Trim(strField)
			strValue = objRegexp.Replace(strLine, "$2")
			strValue = Trim(strValue)
		Else
			' Wscript.Echo ":( " & strLine 
		End If
		If ( Lcase(strField) = "id" ) Then
			nVdisks = nVdisks + 1
			ReDim Preserve vdiskId(nVdisks-1)
			ReDim Preserve vdiskStatus(nVdisks-1)
			ReDim Preserve vdiskState(nVdisks-1)
			ReDim Preserve vdiskCtrlrNdx(nVdisks-1)
			ReDim Preserve vdiskProgress(nVdisks-1)
			vdiskId(nVdisks-1) = strValue
			vdiskCtrlrNdx(nVdisks-1) = ndx
		ElseIf ( Lcase(strField) = "status" ) Then
			vdiskStatus(nVdisks-1) = strValue
		ElseIf ( Lcase(strField) = "state" ) Then
			vdiskState(nVdisks-1) = strValue
		ElseIf ( Lcase(strField) = "progress" ) Then
			if ( Lcase(strValue) = "not applicable" ) Then
				vdiskProgress(nVdisks-1) = ""
			Else
				vdiskProgress(nVdisks-1) = " " & strValue
			End If
		End If
		' Wscript.Echo ">> " & strField & "=" & strValue
	Loop
	' Check battery status
	Set objExecObject = objShell.Exec(strPathToOmreport & "omreport.exe storage battery controller=" & ctrlrId(ndx) & " -fmt lst")
	Do Until objExecObject.StdOut.AtEndOfStream
		strLine = objExecObject.StdOut.ReadLine()
		' Using same objRegexp.Pattern as above
		strField = ""
		if ( objRegexp.Test(strLine) = True ) Then
			strField = objRegexp.Replace(strLine, "$1")
			strField = Trim(strField)
			strValue = objRegexp.Replace(strLine, "$2")
			strValue = Trim(strValue)
		ElseIf ( Lcase(strLine) = "no batteries found" ) Then
			ctrlrBatteryId(ndx) = "No Battery"
		Else
			' Wscript.Echo ":( " & strLine 
		End If
		If ( Lcase(strField) = "id" ) Then
			ctrlrBatteryID(ndx) = strValue
		ElseIf ( Lcase(strField) = "status" ) Then
			ctrlrBatteryStatus(ndx) = strValue
		ElseIf ( Lcase(strField) = "state" ) Then
			ctrlrBatteryState(ndx) = strValue
		End If
	Loop

	ndx = ndx+1
Loop

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Loop through vdisks, to get each adisk (array member disk) from each vdisk

Dim nAdisks
Dim adiskId(), adiskStatus(), adiskState(), adiskVdiskNdx(), adiskProgress()
nAdisks = 0

ndx=0
Do Until ( ndx >= nVdisks )
	Set objExecObject = objShell.Exec(strPathToOmreport & "omreport.exe storage adisk vdisk="& vdiskId(ndx) &" controller=" & ctrlrID(vdiskCtrlrNdx(ndx)) & " -fmt lst")
	Do Until objExecObject.StdOut.AtEndOfStream
		strLine = objExecObject.StdOut.ReadLine()
		' Wscript.Echo "> " & strLine
		' Using same objRegexp.Pattern as above
		if ( objRegexp.Test(strLine) = True ) Then
			strField = objRegexp.Replace(strLine, "$1")
			strField = Trim(strField)
			strValue = objRegexp.Replace(strLine, "$2")
			strValue = Trim(strValue)
		Else
			' Wscript.Echo ":( " & strLine 
		End If
		If ( Lcase(strField) = "id" ) Then
			nAdisks = nAdisks + 1
			ReDim Preserve adiskId(nAdisks-1)
			ReDim Preserve adiskStatus(nAdisks-1)
			ReDim Preserve adiskState(nAdisks-1)
			ReDim Preserve adiskVdiskNdx(nAdisks-1)
			ReDim Preserve adiskProgress(nAdisks-1)
			adiskId(nAdisks-1) = strValue
			adiskVdiskNdx(nAdisks-1) = ndx
		ElseIf ( Lcase(strField) = "status" ) Then
			adiskStatus(nAdisks-1) = strValue
		ElseIf ( Lcase(strField) = "state" ) Then
			adiskState(nAdisks-1) = strValue
		ElseIf ( Lcase(strField) = "progress" ) Then
			if ( Lcase(strValue) = "not applicable" ) Then
				adiskProgress(nAdisks-1) = ""
			Else
				adiskProgress(nAdisks-1) = " " & strValue
			End If
		End If
		' Wscript.Echo ">> " & strField & "=" & strValue
	Loop

	ndx = ndx+1
Loop
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Now we've collected the data, we will analyse the results
Dim ctrlNdx, vdiskNdx, adiskNdx
Dim nWarnings, nFailed, nBattery
Dim strState
nWarnings=0
nFailed=0
nBattery=0

' Loop through controllers
ctrlNdx = 0
if ( nCtrlrs = 0 ) Then
	strMessage = "No Controllers Found!"
Else
	strMessage = ""
End If
Do Until ( ctrlNdx >= nCtrlrs )
	' Wscript.Echo ">> " & ctrlrID(ctrlNdx)
	strState = ctrlrStatus(ctrlNdx) & "/" & ctrlrState(ctrlNdx)
	strMessage = strMessage & "Controller" & ctrlrId(ctrlNdx) & "=" & strState & " [ "
	if ( NOT ctrlrBatteryId(ctrlNdx) = "No Battery" ) Then
		strState = ctrlrBatteryStatus(ctrlNdx) & "/" & ctrlrBatteryState(ctrlNdx)
		if ( InStr(Lcase(strState),"ok/ready") = 1 ) Then
			' OK
		ElseIf ( InStr(Lcase(strState), "degrad" ) > 0  OR InStr(Lcase(strState), "charging" ) > 0 ) Then
			nWarnings = nWarnings + 1
			strState = strState & "**"
		Else
			nBattery = nBattery + 1
			strState = strState & "**"
		End If
		strMessage = strMessage & "Battery" & ctrlrBatteryId(ctrlNdx) & "=" & strState & " ] [ "
	End If
	vdiskNdx = 0
	Do Until ( vdiskNdx >= nVdisks )
		' Does this vdisk belong to the current controller?
		if ( vdiskCtrlrNdx(vdiskNdx) = ctrlNdx ) Then
			strState = vdiskStatus(vdiskNdx) & "/" & vdiskState(vdiskNdx)
			if ( InStr(Lcase(strState), "ok/ready" ) = 1 ) Then
				' OK
			ElseIf ( InStr(Lcase(strState), "degrad" ) > 0  OR InStr(Lcase(strState), "regen" ) > 0 OR InStr(Lcase(strState), "rebuild") > 0 ) Then
				nWarnings = nWarnings + 1
				strState = strState & "**"
			Else
				nFailed = nFailed + 1
				strState = strState & "**"
			End If
			strMessage = strMessage & "Vdisk" & vdiskId(vdiskNdx) & "=" & strState & vdiskProgress(vdiskNdx) & " [ "
			adiskNdx = 0
			Do Until ( adiskNdx >= nAdisks )
				' Does this adisk belong to the current vdisk?
				if ( adiskVdiskNdx(adiskNdx) = vdiskNdx ) Then
					strState = adiskStatus(adiskNdx) & "/" & adiskState(adiskNdx)
					if ( InStr(Lcase(strState), "ok/online") = 1 OR InStr(Lcase(strState), "ok/ready" ) = 1 ) Then
						' Array disks have status "online", hot spares have status "ready"
						' OK
					ElseIf ( InStr(Lcase(strState), "degrad" ) > 0  OR InStr(Lcase(strState), "regen" ) > 0 OR InStr(Lcase(strState), "rebuild") > 0 ) Then
						nWarnings = nWarnings + 1
						strState = strState & "**"
					Else
						nFailed = nFailed + 1
						strState = strState & "**"
					End If
					strMessage = strMessage & adiskID(adiskNdx) & "=" &  strState & adiskProgress(adiskNdx) & " "
				End If
				adiskNdx = adiskNdx+1
			Loop
		strMessage = strMessage & "] "
		End If
		vdiskNdx = vdiskNdx+1
	Loop
	strMessage = strMessage & "]"
	ctrlNdx = ctrlNdx+1
Loop
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Print the message, and exit with the appropriate exit code
if( nFailed > 0 OR nBattery > 0 ) Then
	intExit = intCritical
	strMessage = "CRITICAL: " & strMessage
ElseIf ( nWarnings > 0 OR nCtrlrs = 0 OR nWarnings > 0 ) Then
	intExit = intWarning
	strMessage = "WARNING: " & strMessage
Else
	intExit = intOK
	strMessage = "OK: " & strMessage
End If

WScript.Echo strMessage

WScript.Quit(intExit)

Set objRegexp = Nothing
Set objShell = Nothing
Set objExecObject = Nothing
Set Slot() = Nothing
Set Array_resync() = Nothing
Set Array_failed() = Nothing
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

</script>
</job>