''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' "check_dell_aacraid.wsf"
'
' This script was initially developed by Anstat Pty Ltd for internal use,
' and has kindly been made available to the Open Source community for
' redistribution and further development under the terms of the
' GNU General Public License: http://www.gnu.org/licenses/gpl.html
' 
' This script is supplied 'as-is', in the hope that it will be useful, but
' neither Anstat Pty Ltd nor the authors make any warranties or guarantees
' as to its correct operation, including its intended function.
' 
' Or in other words:
'         Test it yourself, and make sure it works for YOU.
' 
' Authors: George Hansper, Richard Balaganeshan
'                                   e-mail:  Name.Surname@anstat.com.au
'
' 28.07.2004 ver 1.0
'
' Check status of Dell RAID array using Dell PERC 2 utility
'
' This pluging will return the status of the a Dell RAID Array
' This script requires the command line utility "afacli.exe"
' from the package: "PERC 2, 2/Si, 3/Si, 3/Di Management utility (FAST)"
'
' *** Warning: this script has not been tested thoroughly - use at own risk ***
'
' This script is based on an equivalent Perl script for Linux. The following
' empirical information was used to establish the status codes:
' Status info:
' Disk OK and Array OK:
'       OK ACTIVATE
' (may be running on hotspare - slot marked "OK HOTSPARE ACTIVATE")
' Disk OK and Rebuilding
'       OK REBUILD FAILED CRITICAL ACTIVATE
' Disk Failed (unplugged)
'       OK FAILED CRITICAL UNCONFIG EMPTY I/R READY NOTACTIVATE
'       OK EMPTY I/R READY NOTACTIVATE
' Hotspare ready but not in use
'       OK UNCONFIG HOTSPARE ACTIVATE
' Hotspare Disk rebuilding
'       OK REBUILD FAILED CRITICAL HOTSPARE ACTIVATE
' Hotspare Disk online (ie after a failure)
'       OK HOTSPARE ACTIVATE
'
' Disk failed and no hotspare available
'       OK FAILED CRITICAL ACTIVATE
'       OK FAILED CRITICAL HOTSPARE ACTIVATE
'
' From the Dell documentation:
' Status  	 Meaning
' -------	---------
' OK 		The device that resides in this slot is operational. In the example, the device that resides in device slot 0 on enclosure management device 0 is operational.
' ERROR 	The device that resides in this slot has error conditions.
' FAULTY 	The device that resides in this slot has some hardware or data fault.
' REBUILD 	The device that resides in this slot is being rebuilt.
' FAILED 	The device that resides in this slot is in a device array. One member of this device array has an error.
' CRITICAL 	The device that resides in this slot is in a device array that was previously fault-tolerant and is now non-fault-tolerant.
' SCRUB 	The device that resides in this slot is in a device array that is undergoing a parity check operation.
' WARNING 	The device that resides in this slot is likely to fail in the near future.
' UNCONFIG 	The device that resides in this slot is not currently configured as a member of a device array or as a hot spare.
' HOTSPARE 	The device that resides in this slot is configured as a hot spare.
' REBUILDSTOP 	The device that resides in this slot was rebuilding, but the rebuild operation terminated abnormally or unsuccessfully.
' EMPTY 	No physical device resides in this slot.
' I/R READY 	The slot is ready for the physical insertion or removal of a device.
' NOTACTIVATE 	The slot is not activated. The device that resides in the slot cannot be accessed on the SCSI bus.
' ACTIVATE 	The slot is activated. The device that resides in the slot can be accessed on the SCSI bus.
' 

<job>
<runtime>
  <description>
Check status of Dell RAID array using Dell PERC 2 utility

This script requires the command line utility "afacli.exe"
from the package: "PERC 2, 2/Si, 3/Si, 3/Di Management utility (FAST)"
	
Example NRPE_NT Usage:
	command[check_aacraid]=c:\winnt\system32\cscript.exe //NoLogo //T:10 c:\nrpe_nt\check_aacraid.wsf

  </description>
  </runtime>
<script language="VBScript">
Dim strPattern, strLine, details, ndrv_ok, ndrv_resync, ndrv, ndrv_failed
Dim Array_resync(), Array_failed(), Slot()
Dim array_id, drive_slot, drive_scsiId, drive_status
Dim status, disk_faulty, array_fail, array_resyncing, is_hotspare, ndx
Dim disk_online, slot_empty, unconfig
Dim failed_msg, status_msg
Const intOK = 0
Const intWarning = 1
Const intCritical = 2
Dim intExit

Set objRegexp = New RegExp
With objRegexp
.Global = False
.IgnoreCase = True
.Pattern = "."
End With

Set objShell = WScript.CreateObject("WScript.Shell")
Set objExecObject = objShell.Exec("C:\Program Files\PERC2\AFA\afacli open /readonly afa0 ; enclosure show slot ; task list ; controller details ; close ; exit")

ndrv_ok = 0
ndrv_resync = 0
ndrv = 0
ndrv_failed = 0
narrays = -1
REDIM Slot(0)
Slot(0) = "No RAID Disk found"

' Skip all text until 'Enclosure' heading
objRegexp.Pattern = "Enclosure.*Slot.*scsiId"
Do Until objExecObject.StdOut.AtEndOfStream
   strLine = objExecObject.StdOut.ReadLine()
   ' Wscript.Echo "> " & strLine
   if objRegexp.Test(strLine) = True then
      Exit Do
   End If
Loop

' Get status of all drives (until blank line)
objRegexp.Pattern = "\s*([0-9])\s+([0-9])\s+([0-9]:[0-9]+:[0-9])\s+[0-9]\s+(.*)\s*"
Do Until objExecObject.StdOut.AtEndOfStream
   strLine = objExecObject.StdOut.ReadLine()
   ' Wscript.Echo ">> " & strLine
   if strLine = "" then
      Exit Do
   End If

   If objRegexp.Test(strLine) = True Then
      ' Wscript.Echo "$3=" & objRegexp.Replace(strLine, "$3")
      array_id         = objRegexp.Replace(strLine, "$1")
      drive_slot       = objRegexp.Replace(strLine, "$2")
      drive_scsiId     = objRegexp.Replace(strLine, "$3")
      drive_status     = objRegexp.Replace(strLine, "$4")

      details = split(drive_status," ", -1, 1)
      
      If array_id > narrays  Then
         REDIM PRESERVE Array_resync(array_id)
	 REDIM PRESERVE Array_failed(array_id)
      End If

      ndx = 0
      status = "undef"
      is_hotspare = ""
      slot_empty = 0
      disk_online = 0
      array_fail = 0
      disk_faulty = 0
      array_resyncing = 0
      Do Until ndx >= Ubound(details)
         ndx = ndx + 1
         if details(ndx) = "NOTACTIVATE" Then
            disk_online = -1
         ElseIf details(ndx) = "ACTIVATE" Then
            disk_online = 1
	 ElseIf details(ndx) = "FAULTY" Then
	    disk_faulty = 1
         ElseIf details(ndx) = "REBUILD" Then
            array_resyncing = 1
	    Array_resync(array_id) = "Array" & array_id
         ElseIf details(ndx) = "FAILED" Then
            array_fail = 1
	    Array_failed(array_id) = "Array" & array_id
         ElseIf details(ndx) = "CRITICAL" Then
            array_fail = 1
	    Array_failed(array_id) = "Array" & array_id
         ElseIf details(ndx) = "UNCONFIG" Then
            unconfig = 1
         ElseIf details(ndx) = "HOTSPARE" Then
            is_hotspare = "(hotspare)"
         ElseIf details(ndx) = "EMPTY" Then
            slot_empty = 1
         End If
      Loop
      
      If disk_faulty = 1 Then
         status = "Failed"
	 failed_msg = failed_msg & "Slot" & array_id & drive_slot
	 ndrv_failed = ndrv_failed + 1
      ElseIf slot_empty = 1 Then
         ' Empty slots are not errors
         status = "Empty"
         ndrv_ok = ndrv_ok + 1
      ElseIf unconfig = 1 Then
         status = "Unconf"
	 if ( NOT is_hotspare = "" ) Then
            ' HOTSPARE drives are normally UNCONFIG
	    status = "Hotspare"
	    is_hotspare = ""
            ndrv_ok = ndrv_ok + 1
	 End If
      ElseIf disk_online = -1 Then
         status = "Failed"
         failed_msg = failed_msg & "Slot" & array_id & drive_slot
	 ndrv_failed = ndrv_failed + 1
      ElseIf array_resyncing = 1 AND disk_online = 1 Then
         status = "Resync"
         ndrv_resync = ndrv_resync + 1
      ElseIf disk_online = 1 Then
         status = "OK"
         ndrv_ok = ndrv_ok + 1
      Else
         status = "undef"
      End If

      REDIM PRESERVE Slot(ndrv)
      Slot(ndrv) = "Slot" & array_id & drive_slot & " " & status & is_hotspare
      ndrv = ndrv + 1

   End If
Loop

' Report any rebuild in progress
objRegexp.Pattern = ".*Rebuild\s*(\S*).*"
Do Until objExecObject.StdOut.AtEndOfStream
   strLine = objExecObject.StdOut.ReadLine()
   ' Wscript.Echo ">>> " & strLine
   if objRegexp.Test(strLine) = True then
      strRebuild = objRegexp.Replace(strLine, "$1")
   End If

   if ( InStr(strLine, "Executing: controller") = 1 ) Then
      Exit Do
   End If
Loop

' Get status of battery
battery_warning = 0
objRegexp.Pattern = ".*Battery State:\s*(.*\S)\s*"
Do Until objExecObject.StdOut.AtEndOfStream
   strLine = objExecObject.StdOut.ReadLine()
   ' Wscript.Echo ">>>> " & strLine
   if objRegexp.Test(strLine) = True then
      strBattery_state = objRegexp.Replace(strLine, "$1")
      if ( NOT Lcase(strBattery_state) = "not present" ) Then
         if ( NOT Lcase(strBattery_state) = "ok" ) Then
            battery_warning = 1
         End if
         REDIM PRESERVE Slot(ndrv)
	 Slot(ndrv) = "Battery " & strBattery_state
         ndrv = ndrv + 1
      End if
      Exit Do
   End If
Loop

status_msg = Join(Slot, "; ")
resync_msg = Join(Array_resync, "; ")
array_msg = Join(Array_failed, "; ")

If( ndrv_failed <> 0 AND ndrv_resync = 0 ) Then
   status_msg = "CRITICAL " & failed_msg & ": " &status_msg
   intExit = intCritical
ElseIf( ndrv_resync <> 0 OR strRebuild <> "" ) Then
   status_msg = "RESYNC " & resync_msg & " " & strRebuild & ": " & status_msg
   intExit = intWarning
ElseIf ( array_msg <> "" ) Then
   status_msg = "CRITICAL " & array_msg & ": " &status_msg
   intExit = intCritical
ElseIf ( battery_warning = 1 ) Then
   status_msg = "WARNING: " & status_msg
   intExit = intWarning
ElseIf( ndrv = 0 ) Then
   status_msg = "WARNING: " & status_msg
   intExit = intWarning
Else
   status_msg = "OK - " & status_msg
   intExit = intOK
End if

WScript.Echo status_msg
   
WScript.Quit(intExit)

Set objRegexp = Nothing
Set objShell = Nothing
Set objExecObject = Nothing
Set Slot() = Nothing
Set Array_resync() = Nothing
Set Array_failed() = Nothing

</script>
</job>